1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
|
// Copyright Vespa.ai. Licensed under the terms of the Apache 2.0 license. See LICENSE in the project root.
/**
* @author Tony Vaagenes
*/
options {
LOOKAHEAD = 1;
STATIC = false;
UNICODE_INPUT = true;
}
PARSER_BEGIN(Parser)
package com.yahoo.search.query.textserialize.parser;
import java.util.List;
import java.util.ArrayList;
import java.util.Map;
import java.util.LinkedHashMap;
public class Parser {
private DispatchFormHandler dispatchFormHandler;
private Object dispatchContext;
public Parser(java.io.Reader stream, DispatchFormHandler dispatchFormHandler, Object dispatchContext) {
this(stream);
this.dispatchFormHandler = dispatchFormHandler;
this.dispatchContext = dispatchContext;
}
private static String parseString(String in) {
return stripEnclosingQuotes(
in.replace("\\\\", "\\").replace("\\\"", "\""));
}
private static String stripEnclosingQuotes(String in) {
return in.substring(1, in.length() - 1);
}
}
PARSER_END(Parser)
Object start():
{
final Object result;
}
{
result = form()
<EOF>
{ return result; }
}
Object form():
{
final Object result;
}
{
(
result = dispatchForm() |
result = map() |
result = array() |
result = literal()
)
{ return result; }
}
Object literal():
{
final Object result;
}
{
(
result = string() |
result = number() |
result = bool() |
result = null_()
)
{ return result; }
}
String string():
{
Token t;
}
{
t = <STRING>
{ return parseString(t.image); }
}
Double number():
{
Token t;
}
{
t = <NUMBER>
{ return Double.valueOf(t.image); }
}
Boolean bool():
{
Token t;
}
{
t = <BOOLEAN>
{
if ("on".equals(t.image)) return true;
return Boolean.valueOf(t.image);
}
}
Object null_():
{}
{
<NULL>
{ return null; }
}
Map<Object, Object> map():
{
Object key, value;
Map<Object, Object> result = new LinkedHashMap<Object, Object>();
}
{
<OPEN_CURLY>
(
key = form()
value = form()
{ result.put(key, value); }
)*
<CLOSE_CURLY>
{ return result; }
}
Object dispatchForm():
{
Token symbol;
List<Object> arguments;
}
{
<OPEN_PAREN>
symbol = <SYMBOL>
arguments = forms()
<CLOSE_PAREN>
{ return dispatchFormHandler.dispatch(symbol.image, arguments, dispatchContext); }
}
List<Object> forms():
{
Object value;
List<Object> results = new ArrayList<Object>();
}
{
(
value = form()
{ results.add(value); }
)*
{ return results; }
}
List<Object> array():
{
List<Object> result;
}
{
<OPEN_SQUARE>
result = forms()
<CLOSE_SQUARE>
{ return result; }
}
SKIP : { " " | "\n" | "\r" | "\t" | "\f" | "," }
TOKEN : { < OPEN_PAREN: "(" > }
TOKEN : { < CLOSE_PAREN: ")" > }
TOKEN : { < OPEN_CURLY: "{" > }
TOKEN : { < CLOSE_CURLY: "}" > }
TOKEN : { < OPEN_SQUARE: "[" > }
TOKEN : { < CLOSE_SQUARE: "]" > }
TOKEN : { <BOOLEAN: "true" | "false" | "on" | "off" > }
TOKEN : { <NULL: "null" > }
TOKEN : { < STRING: <QUOTE> (<STRING_CHARACTER>)* <QUOTE> > }
TOKEN : { < #STRING_CHARACTER: "\\\\" | "\\\"" | ~["\"", "\\"] > }
TOKEN : { < #QUOTE: "\"" > }
TOKEN : { < NUMBER: (<SIGN>)? (<DIGIT>)+ ("." (<DIGIT>)*)? (<EXPONENT>)? > }
TOKEN : { < #EXPONENT: ["e", "E"] (<SIGN>)? (<DIGIT>)+ > }
TOKEN : { < #SIGN: ["+", "-"] >}
TOKEN : { < #DIGIT: ["0" - "9"] > }
TOKEN : { < SYMBOL: <SYMBOL_FIRST> (<SYMBOL_REST>)* > }
TOKEN : { < #SYMBOL_FIRST: ["a"-"z"] | ["A"-"Z"] |
"+" | "-" | "*" | "/" |
"!" | "?" |
"-" | "_" |
"=" | ">" | "<" > }
TOKEN : { < #SYMBOL_REST: <SYMBOL_FIRST> | ["0" - "9"] | "." > }
|
