Remove "-mode" suffix from filenames

1 files changed, 37 insertions, 0 deletions

diff --git a/lisp/init-go.el b/lisp/init-go.el
new file mode 100644
index 0000000..07141e1
--- /dev/null
+++ b/lisp/init-go.el
@@ -0,0 +1,37 @@
+(defun go-mode-create-imenu-index ()
+    "Create and return an imenu index alist. Unlike the default
+alist created by go-mode, this method creates an alist where
+items follow a style that is consistent with other prog-modes."
+    (let* ((patterns '(("type" "^type *\\([^ \t\n\r\f]*\\)" 1)))
+           (type-index (imenu--generic-function patterns))
+           (func-index))
+      (save-excursion
+        (goto-char (point-min))
+        (while (re-search-forward go-func-meth-regexp (point-max) t)
+          (let* ((var (match-string-no-properties 1))
+                 (func (match-string-no-properties 2))
+                 (name (if var
+                           (concat (substring var 0 -1) "." func)
+                         func))
+                 (beg (match-beginning 0))
+                 (marker (copy-marker beg))
+                 (item (cons name marker)))
+            (setq func-index (cons item func-index)))))
+      (nconc type-index (list (cons "func" func-index)))))
+
+(defun go-mode-create-flat-imenu-index ()
+    "Return a flat imenu index alist. See `go-mode-create-imenu-index'."
+    (apply 'nconc (mapcar 'cdr (go-mode-create-imenu-index))))
+
+(use-package go-mode
+  :init
+  :config
+  (add-hook 'go-mode-hook
+            (lambda ()
+              ;; adjust fill-column
+              (setq-local fill-column 120)
+              ;; use flat imenu index
+              (setq-local imenu-create-index-function
+                          #'go-mode-create-flat-imenu-index))))
+
+(provide 'init-go)